¿Necesitas sacar el nombre del mes de una fecha? ¿O, tal vez, deseas obtener el nombre del día de la semana? Este artículo explica cómo hacer eso (y algunas cosas más) de manera sencilla.
Obtener el número del mes
La forma más conocida de extraer el mes de una fecha es utilizando la función MES.
Esta función nos da como resultado un número entre 1 y 12, que corresponde al mes de la fecha indicada. Su sintaxis es la siguiente:
Entre paréntesis debemos indicar una fecha, de alguna de las siguientes maneras:
- Escribiéndola entre comillas. Por ejemplo: =MES("20/04/2017")
- Haciendo referencia a una celda que contenga la fecha. Por ejemplo: =MES(B3)
- Ingresando una fórmula que devuelva la fecha. Por ejemplo: =MES(HOY())
- Ingresando el número de serie de la fecha. Por ejemplo: =MES(42845). (Este es el modo menos usado. Excel, en su manejo interno, utiliza una serie de números, desde el 1 al 2958465, para representar las fechas entre el 01/01/1900 y el 31/12/9999 inclusive. Aquí puedes leer más sobre la forma en que Excel maneja las fechas.)
Extraer el día, el mes o el año de una fecha son cosas muy parecidas
Así como para sacar el mes de una fecha puedes usar la función MES, puedes obtener el día o el año de una fecha con las funciones DIA y AÑO, respectivamente.
Su sintaxis es idéntica a la de la función MES. Para extraer el día de una fecha es: =DIA(fecha). Para extraer el año de una fecha: =AÑO(fecha)
Todas estas funciones devuelven su resultado en forma de número.
Obtener el nombre del mes
Para extraer el nombre de un mes a partir de una fecha, podemos usar la función TEXTO.
Su sintaxis es la siguiente:
Como primer argumento de la función TEXTO debemos especificar la fecha que contiene el mes buscado. (Podemos hacer esto de cualquiera de las maneras que se mencionan más arriba para indicar la fecha en la función MES.)
El segundo argumento es una cadena de texto preestablecida, mediante la cual le indicamos a Excel cómo deseamos ver el resultado.
En el caso de que queramos que Excel devuelva el nombre completo del mes, la cadena de texto que debemos ingresar como segundo argumento es: "mmmm", comillas incluidas.
=TEXTO("20/04/2017";"mmmm") retorna abril
Si ingresamos la cadena "mmm", Excel devolverá el nombre del mes abreviado, es decir, solo sus tres primeras letras. (ene, feb, mar, etc.)
=TEXTO("20/04/2017";"mmm") retorna abr
Obtener el nombre del día de la semana
Para obtener el nombre del día de la semana, debemos usar la función TEXTO de forma idéntica a la ya explicada, a excepción del segundo argumento.
El segundo argumento en este caso debe ser "dddd" (para que Excel nos devuelva el nombre del día completo) o "ddd" (para que lo muestre abreviado).
=TEXTO("20/04/2017";"dddd") retorna jueves
=TEXTO("20/04/2017";"ddd") retorna ju o jue (dependiendo de la versión de Excel)
Para extraer el nombre del mes de la fecha de hoy puedes usar la fórmula =TEXTO(HOY();"mmmm").
Para extraer el nombre del día de la semana de la fecha de hoy puedes usar la fórmula =TEXTO(HOY();"dddd")
Con minúscula, mayúscula o mayúscula inicial
Un detalle importante es que la función TEXTO devuelve tanto los nombres de los meses como de los días siempre en minúscula. Para que los muestre en mayúsculas debemos introducir la función TEXTO dentro de la función MAYUSC, del siguiente modo:
=MAYUSC(TEXTO(fecha; formato))
Para que los nombres sean retornados solo con la primera letra mayúscula y las demás en minúscula, debemos introducir la función TEXTO dentro de la función NOMPROPIO:
=NOMPROPIO(TEXTO(fecha; formato))
=MAYUSC(TEXTO("15/07/2017";"mmmm")) retorna JULIO
=MAYUSC(TEXTO("15/07/2017";"ddd")) retorna SÁ o SÁB
=NOMPROPIO(TEXTO("15/07/2017";"mmmm")) retorna Julio
=NOMPROPIO(TEXTO("15/07/2017";"ddd")) retorna Sá o Sáb
¿Te pareció práctica esta información? Si es así, te invito a suscribirte a nuestro boletín gratuito, para mantenerte al tanto de los artículos y noticias más relevantes que se publiquen en el blog.
Ingreso la fórmula =TEXTO(MES(A1),"mmmm") y me sale enero, pero cuando arrastro la formula a las otras fechas me coloca enero en todas las celdas de la columna. Es decir, que no me coloca febrero, marzo, etc. cuando le toca hacer el cambio. Saludos.
Hola, Vicente.
La fórmula debería ser, simplemente, =TEXTO(A1,"mmmm").
Esto es porque la función TEXTO extrae el mes directamente de la fecha.
La función MES da como resultado el mes de la fecha indicada, en forma de número.
La función TEXTO puede servir para devolver el nombre de un mes a partir de una fecha.
Pero, al menos en este caso, no es necesario combinarlas.
¡Saludos!
Buenos días,
¿se puede realizar BUSCARV con el texto extraído? Al intentar me aparece #N/A.
Hola, Vicente.
Sí, se puede usar BUSCARV.
Pero, lamentablemente, no sé porqué te puede estar dando ese valor de error.
Necesitaría conocer mejor el contexto.
Saludos.
Hola!
¿Qué debería agregar si la fecha tiene, además, la hora? Por ejemplo:
01.01.2019 00:00
Me esta tomando los dos últimos números...
Hola, Jan.
El formato que pones como ejemplo, está casi bien.
El único detalle para que funcione es cambiar los puntos (que separan las partes de la fecha) por barras inclinadas o guiones.
Así:
01/01/2019 00:00
o
01-01-2019 00:00
Espero que te sirva.
La solución que te compartí funciona en la mayoría de los casos.
Saludos.
Hola.
¿Cómo hacer para que TEXTO devuelva Sep y no Sept?
Ej.:
Texto(A1;"mmm")
Hola, Alex.
La respuesta que da Excel en estos casos depende de la configuración regional del sistema.
No hay forma de modificarla directamente desde la configuración de Excel, al menos que yo sepa.
Una solución sería corregir la fórmula.
Por ejemplo:
SI( TEXTO(A1;"mmm")="Sept"; "Sep"; TEXTO(A1;"mmm"))
Saludos.
¿Cómo se puede obtener la fecha inicial a partir del nombre de un mes?
Ejemplo: pongo enero y, en otra celda, con alguna formula, quisiera que me arrojara el 1er día de ese mes.
Hola, David. ¿Cómo estás?
Te paso dos formulas que te pueden servir para lo que necesitas.
Para ambas fórmulas supongamos que el nombre del mes está en la celda A1.
Primera opción: Da como resultado una fecha con este formato: 1/enero/2023.
="1/" & A1 & "/2023"
Segunda opción: Da como resultado una fecha con este formato: 1/1/2023.
=FECHA( 2023 ; MES( "1/" & A1 & "/2023" ); 1 )
La primera fórmula es más simple, la segunda es más sólida.
Espero que con alguna de ellas puedas resolver tu problema.
Saludos.
PD: Estas fórmulas solamente crean fechas del 2023. Puedes cambiar el año manualmente.
También puedes tomar el año de una celda. En ese caso las fórmulas quedarían así (suponiendo que el año estuviera en la celda B1):
="1/" & A1 & "/" & B1
=FECHA( B1; MES( "1/" & A1 & "/" & B1 ); 1 )
Estoy introduciendo la función TEXTO para que me devuelva el mes y la fórmula no devuelve el resultado; también quisiera que la función TEXTO me diera mes y año.
Hola, Georjan.
Sinceramente, no sabría decirte por qué la función te está fallando.
¿Tal vez sea porque la fecha, desde la que quieres obtener el mes, está siendo interpretada por Excel como un texto, en lugar de como una fecha?
Para que la función devuelva el nombre completo del mes más el año (y suponiendo que la fecha estuviera en A1), deberías usar la siguiente fórmula:
=TEXTO(A1;"mmmm aaaa")
Si no funcionara, prueba con:
=TEXTO(A1;"mmmm yyyy")
Dependiendo de la configuración del sistema, el año se debe escribir con aes ("aaaa") o con yes ("yyyy").
Saludos.
Hola. Veo que, cuando la celda de donde se va a tomar la fecha, está vacía, la fórmula pone "enero". ¿Qué se debe añadir a la fórmula, para que no ponga "enero" y deje en blanco el resultado?
Hola, Adrián. Intentaré responder del modo más sencillo posible:
Llamémosle FÓRMULA a la fórmula actual que devuelve "enero" como resultado y A1 a la celda donde está la fecha.
Tendría que quedar así:
=SI( A1="" ; "" ; FÓRMULA )
La función SI evalúa una condición y devuelve uno de dos resultados predeterminados, dependiendo de si la condición se cumple o no.
En este caso, si la condición se cumple, es decir, si A1 está vacía, la función devuelve como resultado la celda vacía, de lo contrario, devuelve el resultado de la FÓRMULA.
Dinos cómo te fue.
Espero que te sirva.
¡Saludos!
Creo que faltó explicar: si tiene 12 cómo hacer para que ponga Diciembre; 10, Octubre, etc., etc.
Hola, Luis.
El artículo se centra más bien en obtener el nombre del mes o del día de la semana a partir de una fecha.
De todos modos gracias por la sugerencia.
Espero revisar todos los artículos pronto y tomaré en cuenta tu comentario.
¡Saludos!