Clases Excel
Domingo, 06 Marzo 2016 07:56

6 nuevas funciones de Excel que simplificarán tu trabajo cotidiano

Valora este artículo
(3 votos)

Excel acaba de incorporar 6 nuevas funciones que simplificarán algunas de las tareas más comunes a las que se enfrentamos diariamente todos los usuarios de Excel, como la concatenación, los SI anidados y hallar máximos y mínimos con condiciones. Ya no será tan necesario construir fórmulas complicadas e interminables.

Funciones de Excel febrero 2016 1

 

Según ha declarado el equipo de Office, las 6 nuevas funciones se eligieron en base a sugerencias de los usuarios y son parte de la mejora continua propuesta a partir del lanzamiento de Excel 2016. Por ahora, solamente están disponibles en algunas versiones de Excel, específicamente en Office 365, Excel Online y Excel Mobile (los dos últimos, gratuitos).

 

Las nuevas funciones son UNIRCADENAS (en inglés: TEXTJOIN) y CONCAT (que sustituye a CONCATENAR) para combinar listas o rangos de cadenas de texto, MAX.SI.CONJUNTO (MAXIFS) y MIN.SI.CONJUNTO (MINIFS) para encontrar el máximo o mínimo en un rango con una o más condiciones y SI.CONJUNTO (IFS) y CAMBIAR (SWITCH) para evitar las funciones SI anidadas. Veamos algunos detalles más sobre cada una de ellas.

 

 

UNIRCADENAS y CONCAT

Una tarea muy común para cualquier usuario de Excel es combinar textos de diferentes celdas. Hasta hoy, si necesitábamos unir todos los textos de un rango, la única opción disponible (excluyendo el uso de macros) era especificar cada celda individualmente, mediante la función CONCATENAR o con el operador &.

 

Por ejemplo, para unir todos los textos de las celdas A2 a E2, separados por comas, lo más probable era que empleáramos una de estas dos fórmulas:

=CONCATENAR(A2; ", ";B2; ", ";C2;", ";D2;", ";E2)

=A2&", "&B2&", "&C2&", "&D2&", "&E2

 

Funciones de Excel febrero 2016 2

 

Funciones de Excel febrero 2016 3

 

 

Pero la ventaja de las nuevas funciones UNIRCADENAS y CONCAT es que nos permiten concatenar rangos enteros. UNIRCADENAS admite, además, la especificación un delimitador (como la coma o el espacio) para que Excel lo intercale entre término y término. También nos permite indicar si deben ignorarse las celdas vacías que hubiera en el rango.

 

Usando el ejemplo anterior, con UNIRCADENAS podríamos resolverlo así:

=UNIRCADENAS(", "; VERDADERO;A2:E2)

 

Teniendo en cuenta que, en lugar de VERDADERO podemos colocar un 1 (y en lugar de FALSO, un cero), la fórmula incluso podría abreviarse más:

=UNIRCADENAS(", "; 1;A2:E2)

 

Como primer argumento debe especificarse el término delimitador; en segundo lugar, si se deben saltear las celdas vacías y, finalmente, el rango del cual Excel deberá tomar los textos a unir.

 

Funciones de Excel febrero 2016 4

 

Funciones de Excel febrero 2016 5

 

 

Por otra parte, la función CONCAT es muy similar a CONCATENAR (a la que sustituye) con la mejora de admitir rangos de los cuales extraer los textos. A diferencia de UNIRCADENAS, no permite intercalar un separador entre término y término, ni tampoco incluir celdas vacías (las excluye de forma predeterminada).

 

Puedes obtener una descripción más detallada sobre estas funciones en los siguientes enlaces UNIRCADENAS y CONCAT, de la ayuda de Office 2016.

 

 

SI.CONJUNTO y CAMBIAR

La nuevas funciones SI.CONJUNTO y CAMBIAR ofrecen algunas alternativas al uso de las funciones SI anidadas. No hacen posible la erradicación total de los SI anidados, pero, al menos, simplifican el trabajo en dos de sus estructuras típicas.

 

Las funciones anidadas son aquellas en las que una función SI se inserta dentro de otra función SI, siguiendo la forma genérica: "SI(SI(SI()))". Y, si bien, la función SI es una de las más útiles en Excel y usar SI anidados es una práctica muy común, a la mayoría de los usuarios les resultan complejas las anidaciones y tratan de evitarlas.

 

Por eso creo que estas dos nuevas funciones pueden lograr buena aceptación, aunque habrá que esperar bastante hasta que se hagan de uso masivo. 

 

La función SI.CONJUNTO permite especificar una serie de condiciones en una sola función, de manera lineal y sin necesidad de anidar nada. Cada condición es seguida por el resultado que deberá devolverse si la condición se cumple. Esto hace que la función sea muy fácil de entender.

 

El patrón que sigue la función SI.CONJUNTO es el siguiente:

Condición1; Resultado en caso de cumplirse
Condición2; Resultado en caso de cumplirse
Condición3; Resultado en caso de cumplirse
Y así sucesivamente…

 

El límite son 254 argumentos, es decir, 127 pares Condición-Resultado.

 

Un detalle importante a tener en cuenta es que, cuándo la primera condición se cumple, la función se detiene y devuelve el resultado especificado para dicha condición.

 

Veamos un ejemplo. Supongamos que debes calificar los exámenes de un grupo de personas; la calificación que le corresponde a cada uno está determinada por el puntaje que hayan obtenido.

Un puntaje mayor o igual a 90 equivale a una calificación A.
Un puntaje entre 80 y 89 equivale a una calificación B.
Un puntaje entre 70 y 79 equivale a una calificación C.
Un puntaje entre 60 y 69 equivale a una calificación D.
Un puntaje menor a 60 equivale a "Reprobado".

 

Usando SI anidados la fórmula podría haber sido así:

=SI(C1>=90;"A";SI(C1>=80;"B";SI(C1>=70;"C";SI(C1>=60;"D";"Reprobado"))))

 

Funciones de Excel febrero 2016 6

 

 

Con la nueva función SI.CONJUNTO, la fórmula adquiere una estructura más clara:

=SI.CONJUNTO(C1>=90;"A";C1>=80;"B";C1>=70;"C";C1>=60;"D";C1<60;"Reprobado")

 

Funciones de Excel febrero 2016 7

 

 

La fórmula puede leerse así: Si el puntaje en C1 es mayor o igual a 90, entonces la calificación es A. De lo contrario, si el puntaje en C1 es mayor o igual a 80, la calificación es B. De lo contrario, si el puntaje en C1 es mayor que o igual a 70, la calificación es C y así sucesivamente. Es bastante fácil escribir la fórmula de esta manera y también es fácil de leer y de entender lo que hace.

 

Las condiciones con sus resultados correspondientes se alistan una a continuación de la otra:

C1>=90;"A"
C1>=80;"B"
C1>=70;"C"
C1>=60;"D"
C1 <60;"Reprobado"

 

La función CAMBIAR también se ocupa de evaluar múltiples condiciones, pero, como es lógico, tiene algunas diferencias respecto a SI.CONJUNTO. Una de las principales es que, en lugar de especificar una serie de expresiones lógicas, se especifica una sola expresión (generalmente una referencia de celda), cuyo valor se comparara con una serie de valores posibles, en busca de una coincidencia.

 

Como primer argumento se indica una referencia de celda (o una fórmula) y, luego, una serie de los posibles valores que el primer argumento pudiera contener, junto con los resultados que la función deberá retornar en caso de coincidencia.

 

Como último argumento puede especificarse un resultado "predeterminado", que será devuelto en caso de que ninguno de los valores propuestos equivalga al resultado exacto de la expresión.

 

La estructura básica es la siguiente:

Celda o fórmula a evaluar
Primer valor posible; Resultado en caso de coincidencia
Segundo valor posible; Resultado en caso de coincidencia
Tercer valor posible; Resultado en caso de coincidencia
Y así sucesivamente…
[Resultado predeterminado, en caso de que no haya ninguna coincidencia]

 

La función CAMBIAR compara la expresión del primer argumento con cada una de las posibles respuestas indicadas y, cuando encuentra la primera coincidencia exacta, se detiene y devuelve el resultado correspondiente.

 

En el siguiente ejemplo se determina el nombre de la aplicación que debe usarse para abrir un archivo, en base a su extensión.

Si la extensión es xlsx, la aplicación que abre el archivo es Excel.
Si la extensión es docx, la aplicación que abre el archivo es Word.
Si la extensión es ddtx, la aplicación que abre el archivo es PowerPoint.

 

Usando una fórmula con SI anidados, la solución podría ser:

=SI(B2="xlsx";"EXCEL";SI(B2="docx";"WORD";SI(B2="pptx";"POWERPOINT";"")))

 

Funciones de Excel febrero 2016 8

 

 

Con la función CAMBIAR, puede expresarse de este modo:

=CAMBIAR(B2;"xlsx";"EXCEL";"docx";"WORD";"pptx";"POWERPOINT")

 

Funciones de Excel febrero 2016 9

 

 

La fórmula pudiera leerse así: Si la extensión en B2 es xlsx, entonces la aplicación es EXCEL. De lo contrario, si es docx, la aplicación es WORD. De lo contrario, si es pptx, la aplicación es POWERPOINT.

 

La forma en que se distribuyen sintácticamente los datos en la función es la siguiente:

B2
"xlsx";"EXCEL"
"docx";"WORD"
"pptx";"POWERPOINT"

 

La principal ventaja de CAMBIAR es que evita la repetición de la misma expresión vez tras vez (en este caso, se evita repetir "B2="). Pero esta ventaja de la función implica también una limitación: Solo puede usarse cuando evaluamos los diferentes resultados posibles para una misma celda (o para una misma fórmula).

 

Otra limitante: solo puede evaluar igualdades, si el valor de una celda o el resultado de una fórmula es idéntico a otro. No puede, por ejemplo, evaluar si es mayor o distinto que otro.

 

Puedes obtener una descripción más detallada sobre estas funciones en los siguientes enlaces SI.CONJUNTO y CAMBIAR, de la ayuda de Office 2016.

 

 

MAX.SI.CONJUNTO y MIN.SI.CONJUNTO

Si estás familiarizado con CONTAR.SI.CONJUNTO, SUMAR.SI.CONJUNTO y PROMEDIO.SI.CONJUNTO, las nuevas funciones MAX.SI.CONJUNTO y MIN.SI.CONJUNTO no deberían necesitar mucha explicación. Era casi lógico que alguna vez llegaran a la existencia, y en realidad, demoraron más de lo esperado.

 

Las clásicas funciones MAX y MIN, devuelven, respectivamente, el máximo y mínimo valor de un rango. Pero, ¿qué sucede si necesitas imponer ciertas condiciones? Por ejemplo, si desearas hallar el menor valor superior a cero, o el mayor valor del mes de junio… Para aplicar condiciones a las funciones MAX y MIN, hasta ahora no teníamos más remedio que combinarlas con la función SI (e incluso mezclar alguna otra función, dependiendo de las circunstancias).

 

Sin embargo, ahora ya no será tan necesario. Con las funciones MAX.SI.CONJUNTO y MIN.SI.CONJUNTO puedes especificar desde una a 126 condiciones a la búsqueda del valor máximo o mínimo de un rango. Las condiciones pueden ser aplicadas al propio rango donde están los valores a evaluar, o en celdas adyacentes.

 

En julio del 2015 publiqué un artículo donde se daban ideas para encontrar máximos y mínimos con condiciones. Ahora veamos, la forma en que pueden resolverse este tipo de situaciones usando las nuevas funciones MAX.SI.CONJUNTO y MIN.SI.CONJUNTO.

 

Por ejemplo, supongamos que, de una lista que detalla las ventas de varias sucursales entre 2013 y 2015, debemos averiguar: cuál fue el mayor monto vendido en 2014, entre todas las sucursales, y también cuál fue el menor monto vendido durante el mismo año, excluyendo el valor de venta cero.

 

La sintaxis de las funciones MAX.SI.CONJUNTO y MIN.SI.CONJUNTO, son bastante intuitivas. Tienen la siguiente estructura:

Rango de valores a evaluar
Rango donde se encuentra el primer criterio
Primer criterio
Rango donde se encuentra el segundo criterio
Segundo criterio
Y así sucesivamente...

 

Veamos como resolver el ejemplo antes propuesto:

 

La forma de obtener el mayor monto vendido en 2014 entre todas las sucursales:

 

Funciones de Excel febrero 2016 10

 

 

La forma de obtener el menor monto vendido durante el mismo año, excluyendo el valor de venta cero:

 

Funciones de Excel febrero 2016 11

 

 

Las fórmulas respectivas serían:

=MAX.SI.CONJUNTO(C2:C13;A2:A13;2014)

 

=MIN.SI.CONJUNTO(C2:C13;A2:A13;2014;C2:C13;">0")

 

Puedes obtener una descripción más detallada sobre estas funciones en los siguientes enlaces MAX.SI.CONJUNTO y MIN.SI.CONJUNTO, de la ayuda de Office 2016.

 

 

¡Pruébalas!

Reitero que estas funciones, por el momento, solo están disponibles para los suscriptores de Office 365 con Excel 2016 instalado en su equipo, para los usuarios de Excel Mobile y para los usuarios de Excel Online. Pero, como el acceso a Excel Online es gratuito para todo el que tenga una cuenta de Microsoft (por ejemplo, una cuenta de correo de Hotmail o Outlook), si lo deseas puedes probar allí las nuevas funciones sin demasiados inconvenientes. Las capturas de pantalla de este artículo, sin ir más lejos, fueron tomadas de Excel Online. Aquí te dejo el enlace: office.live.com/start/Excel.aspx?omkt=es-ES.

 

Si bien es cierto que estas funciones no causarán una revolución de inmediato (la mayoría de las versiones de Excel instaladas en el mundo hoy ni siquiera las tienen disponibles), es bueno saber que existen y estar preparados para usarlas cuando sea necesario. Siempre es ventajoso poder anticiparnos a lo que viene, estar unos pasos más adelante.

 

En futuros artículos seguiré analizando las novedades de Excel 2016. Si no quieres perdértelos te invito a suscribirte gratuitamente a nuestro boletín o a visitar regularmente la web.

 

Visto 5670 veces Modificado por última vez en Miércoles, 13 Abril 2016 22:33

Deja un comentario

Los campos imprescindibles están marcados con asterisco (*). Tu dirección de correo nunca será publicada.

3 comentarios

  • Enlace al Comentario Clases Excel Martes, 10 Mayo 2016 05:57 publicado por Clases Excel

    Muchas gracias a ustedes Antonio y Alejandro. Me alegra mucho que les sea útil la información. ¡Saludos!

  • Enlace al Comentario Alejandro Nadi Lunes, 09 Mayo 2016 09:36 publicado por Alejandro Nadi

    De mucha ayuda todo tu contenido. Mil gracias y muchas bendiciones.

  • Enlace al Comentario Antonio Ricaurte Rojas Lunes, 07 Marzo 2016 03:09 publicado por Antonio Ricaurte Rojas

    Gracias por la explicación de estas nuevas funciones.

Suscríbete a nuestro Boletín gratuito

Recibe periódicamente en tu email los últimos artículos, tutoriales y otras novedades de Excel.


Tus datos son confidenciales, nunca serán compartidos con nadie.

Inicio    Contacto    Términos y condiciones    Mapa del sitio

Ir arriba

Desarrollado por www.espectradesign.com