Clases Excel
Domingo, 28 Septiembre 2014 00:34

Contar las palabras de una celda

Valora este artículo
(2 votos)

Hasta la fecha Excel no trae ninguna función que nos permita obtener la cantidad de palabras que contiene una celda. Para hallar ese resultado debemos apelar a una combinación de funciones. Veamos cómo hacerlo.

Contar palabras 1

 

No todos los textos que leamos en Excel (ni en ningún otro lugar) serán perfectos en su estructura. Pero comencemos por considerar como contar las palabras de un texto “ideal”, para entender mejor el procedimiento. Luego analizaremos como lidiar con las “variaciones”.

 

 

La situación ideal

El texto “ideal” es aquel en el que se alternan rigurosamente las palabras y los espacios que las separan. De tal modo que haya una secuencia de: palabra-espacio-palabra-espacio-palabra…

 

Como el texto “ideal” empieza y termina por una palabra, la cantidad de espacios será igual a la cantidad de palabras menos 1.

 

Por eso, una forma bastante simple de saber la cantidad de palabras que hay en un texto es contar la cantidad de espacios que contiene y sumarle 1.

Cantidad de Palabras = Cantidad de Espacios + 1

 

Entonces, ¿hay en Excel alguna función que cuente las veces que se repite un carácter (por ejemplo: un espacio), dentro de un texto? No. A decir verdad, tampoco hay una función que haga eso. Pero sí hay una función que nos permite contar la cantidad de caracteres de un texto y otra que nos permite “eliminar” un carácter (por ejemplo: un espacio) de un texto. Esas funciones se llaman respectivamente LARGO y SUSTITUIR y con ellas, más un poco de ingenio, podremos resolver el problema.

 

Para que la explicación sea más simple, dividiremos el proceso en una serie de pasos. Lo que haremos es:

 

1. Contar todos los caracteres del texto

2. Eliminar todos los espacios del texto

3. Contar los caracteres del texto sin espacios

4. Restar la cantidad de caracteres del texto sin espacios a la cantidad de caracteres del texto con espacios

 

Así obtendremos la cantidad de espacios. La cantidad de palabras, según deducimos más arriba, será igual a la cantidad de espacios más 1.

 

 

Contar todos los caracteres del texto

La función LARGO, que cuenta el largo de una cadena de texto, tiene una sintaxis sumamente sencilla:

=LARGO(texto)

 

Como argumento debemos indicar un texto, de alguna de las siguientes maneras:

 

1. Escribiéndolo directamente, entre comillas. Por ejemplo: =LARGO("El cielo es azul.")

2. Haciendo referencia a una celda que contenga un texto. Por ejemplo: =LARGO(B4)

3. Ingresando una fórmula que devuelva un texto. Por ejemplo: =LARGO(CONCATENAR(“El cielo “;”es azul.”))

 

Contar palabras 2

 

 

Eliminar todos los espacios del texto

La función SUSTITUIR sirve para sustituir una porción de un texto por otro texto. Su sintaxis es:

=SUSTITUIR(texto; porción de texto a cambiar; porción de texto que la reemplaza)

 

Los tipos de datos que admite como argumentos son los mismos que la función LARGO: un texto, una referencia de celda o una fórmula.

 

Si sustituimos un carácter por ningún valor, la función lo eliminará, de modo que con la siguiente fórmula eliminamos los espacios de un texto:

=SUSTITUIR("El cielo es azul."; " "; "")

 

En el texto los espacios (" ") se han sustituidos por cadenas de texto vacías (""), por lo que es resultado de la función será: Elcieloesazul.

 

Contar palabras 3

 

 

Contar todos los caracteres del texto sin sus espacios

Combinando las funciones SUSTITUIR y LARGO, obtenemos el largo del texto sin sus espacios:

=LARGO(SUSTITUIR("El cielo es azul.";" ";""))

 

Contar palabras 4

 

 

La fórmula completa

Suponiendo que el texto a avaluar esté en B3, la fórmula completa sería:

=LARGO(B3)-LARGO(SUSTITUIR(B3;" ";""))+1

 

Contar palabras 5

 

 

Cuando no todo es tan perfecto

Como indicamos al inicio del artículo, esta fórmula da el resultado correcto solo si se cumple la secuencia palabra-espacio-palabra-espacio-palabra…

 

Pero si la celda evaluada estuviera vacía, la fórmula nos devolvería, erróneamente, 1 en vez de cero. Y si el texto tuviera más de un espacio entre cada palabra, también retornaría una cantidad inexacta.

 

Para que no devuelva 1 si la celda está vacía, podemos agregar un SI a la fórmula, de la siguiente manera:

=SI(B3="";0;LARGO(B3)-LARGO(SUSTITUIR(B3;" ";""))+1)

 

Si la celda B3 está vacía (B3=""), el resultado de la función será cero (0), de lo contrario devolverá el resultado de LARGO(B3)-LARGO(SUSTITUIR(B3;" ";""))+1.

 

Por último, ¿cómo podemos eliminar el exceso de espacios si los hubiera? Afortunadamente existe una función que hace justamente eso. Se llama ESPACIOS (o RECORTAR en Excel 2010).

 

Su objetivo es simple: si un texto contiene espacios al inicio o al final, los elimina y también elimina los espacios excedentes entre palabras.

 

De manera que, antes que nada, debemos interceptar el texto a evaluar y depurarlo con la función ESPACIOS.

 

La fórmula final, totalmente aplicable, sería:

=SI(ESPACIOS(B3)="";0;LARGO(ESPACIOS(B3))-LARGO(SUSTITUIR(ESPACIOS(B3);" ";""))+1)

 

Contar palabras 6

 

 

Dependiendo de las circunstancias, entonces, podemos hacer uso de la fórmula que más nos convenga.

 

Visto 4138 veces Modificado por última vez en Miércoles, 30 Marzo 2016 18:36

Deja un comentario

Los campos imprescindibles están marcados con asterisco (*). Tu dirección de correo nunca será publicada.

2 comentarios

Suscríbete a nuestro Boletín gratuito

Recibe periódicamente en tu email los últimos artículos, tutoriales y otras novedades de Excel.


Tus datos son confidenciales, nunca serán compartidos con nadie.

Inicio    Contacto    Términos y condiciones    Mapa del sitio

Ir arriba

Desarrollado por www.espectradesign.com